Library data?

Acá en este foro si usas el buscador hay bastante informacion de eso.

checa acá.

Hola alexis, no necesariamente la estructura de un Library Data es así, en realidad un LibDat puede contener cualquier cosa y lo que usted expuso es una de las miles formas de usarlo.

Le coloco unos ejemplos de LibDats:

Un carácter (@)
88B20C0000FB92004

Un programa SysRPLⁱ
88B20F0000D9D20B2130

Una lista
88B20F000047A20B2130

Un Bint (1869Fh)
88B20F000011920F9681

Datos varios (3322h)
88B20900003322

Use H-> para convertir estas cadenas en Library Data.

Use ->A 10 + A-> para conseguir el objeto contenido en "estos" Library Data (excepto para el caso de Datos varios).

Saludos.
- Gaak -

Usando el OpenLD para abrir library data creados por MakeLD:
Quote:

***** Pone en la pila una lista con todos los nombres globales ( ID )
***** del directorio actual que contienen un LIBRARY DATA que sea lista y
***** tenga como primer elemento a # 4BF ( 1215 )
***** Llama a OpenLD1215

NULLNAME ArchLibData ( --> {} )
:: NULL{}
****** pone lista con los IDs del directorio actual que contengan library data
%26 DOTVARS%
****** si esa lista es vacía deja en la pila una lista vacía y sale
2DUP EQUALcase DROP
toLEN_DO ( {} {}' )
DUPINDEX@ NTHCOMPDROP ( {} {}' id )
DUPSAFE@ DROP ( {} {}' ID LibD )
OpenLD1215 ITE ( {} {}' ID flag )
:: ROT SWAP>HCOMP_ SWAP ;
DROP
LOOP ( {} {}' )
DROP ( {}' )
***** Orden alfabético
ROMPTR xSORT
;

**************************************************************************************
********** Si el libdata es una lista cuyo primer elemento es # 4BF ( 1215 ) pone TRUE
********** Si no lo es pone FALSE

NULLNAME OpenLD1215 ( libdata -> flag )
:: TOTEMPOB
CODE
A=DAT1 A
AD1EX
LC(5) =DOLIST
DAT1=C A
D1=D1+ 5
LC(5) =DOBINT
DAT1=C A
D1=A
GOVLNG =Loop
ENDCODE ( object )
******* si objeto no es lista lo borra, pone FALSE y sale ****************************
DUPTYPELIST? NOTcase DROPFALSE ( {} || FALSE )
********** si objeto es lista vacía la borra, pone FALSE y sale **********************
DUPNULLCOMP? case DROPFALSE ( {} || FALSE )
******* Si el primer elemento de lista es # 4BF pone TRUE. Si no lo es pone FALSE ****
CARCOMP ( obj_head )
# 4BF EQUAL ( flag )
;

ArchLibData funciona correctamente.

Pero si en el directorio actual hay LibDatGaaK la calculadora falla.
¿ Cómo puedo diferenciar los dos tipos de library data ?
Con el comando TYPE los dos tipos de library data arrojan 26.
**************************************************************************************
...
...
...

Parece que usando:

FLASHPTR 2 A5 BINT14 BINT15 SUB$

un library data creada por MakeLD nos da: "00"

y un LibDataGaak nos da otra cosa: "20" , "30" , ...

Si en la pila hay un LibDataGaak y se hace el

TOTEMPOB
CODE
...
ENDCODE

del OpenLD...., arroja una lista con PTRs xxxxx y otras cosas incomprensibles.

*************************************************************************************

Para evitarlo ahora reconozco los LibData creados por MakeLD1215 con el comando FLASHPTR 2 A5 ( x->H )
Quote:

***** Pone en la pila una lista con todos los nombres globales ( ID )
***** del directorio actual que contienen un LIBRARY DATA creado por MakeLD1215
***** Llama a DUPIsLibData1215?

NULLNAME ArchLibData ( --> {} )
:: NULL{}
****** pone lista con los IDs del directorio actual que contengan library data
%26 DOTVARS%
****** si esa lista es vacía deja en la pila una lista vacía y sale
2DUP EQUALcase DROP
toLEN_DO ( {} {}' )
DUPINDEX@ NTHCOMPDROP ( {} {}' id )
DUPIsLibData1215?( {} {}' ID flag )
ITE
:: ROT SWAP>HCOMP_ SWAP ;
DROP
LOOP ( {} {}' )
DROP ( {}' )
***** Orden alfabético
ROMPTR xSORT
;

**************************************************************************************
********** Si el libdata contenido en id es creado por MakeLD1215 agrega TRUE
********** Si no lo es agrega FALSE
********** se supone que id es una variable que si existe en el directorio actual

NULLNAME DUPIsLibData1215? ( id -> id flag )
:: DUPSAFE@ DROP ( id Libdata )
FLASHPTR 2 A5 ( id $ )
**** si el LibData es creado por MakeLD1215 pone TRUE
DUP BINT11 BINT15 SUB$ "FB400" EQUAL ( id $ flag )
**** si el LibData es un PTR xxxxx pone FALSE
SWAP BINT6 BINT10 SUB$ "A0000" EQUALNOT ( id flag flag' )
AND ( id flag )
;

Ahora ArchLibData funciona sin importar que tipo de LibData hay en el directorio actual.
el numero 1215 en hexadecimal es 4BF, por eso se escribió el "FB400"
***************************************************************************************
Las letras en rojo se cambian para su uso en otra biblioteca.

El library Data verdadero es el que crea la calculadora con el formato que le da, pero no es el unico, siempre tiene el numero entero system Binario que es el numero de la biblioteca.

Pero debido a las entradas, programas, y habilidades, se ha logrado no solo crear un library data o CODE con el prologo de los objetos, hasta que se llega a obtener un library data pero de otra manera, como las bibliotecas, que guardan en sus varaibles al objeto en cuestion.